如何测试某个属性是否存在于某些XML中(How to test if an attribute exists in some XML)

 
 
 你会如何执行Arduino的reactimate ？ 
 
 
 我会通过执行具有可观察副作用的IO操作来间接执行它们。 然后，在withArduino内部，我会观察这种副作用并运行相应的Arduino命令。 
 
 这是一些示例代码。 首先，让我们看看进口产品。 
 
{-# LANGUAGE GeneralizedNewtypeDeriving, ScopedTypeVariables #-}

import Control.Monad.IO.Class
import Data.IORef
import Data.Word
import Reactive.Banana
import Reactive.Banana.Frameworks
import Text.Printf
 
 由于我没有arduino，所以我不得不模拟来自hArduino的一些方法。 
 
newtype Arduino a = Arduino (IO a)
  deriving (Functor, Applicative, Monad, MonadIO)

newtype Pin = Pin Word8

pin :: Word8 -> Pin
pin = Pin

digitalWrite :: Pin -> Bool -> Arduino ()
digitalWrite (Pin n) v = Arduino $ do
    printf "Pretend pin %d on the arduino just got turned %s.\n"
           n (if v then "on" else "off")

digitalRead :: Pin -> Arduino Bool
digitalRead (Pin n) = Arduino $ do
    printf "We need to pretend we read a value from pin %d.\n" n
    putStrLn "Should we return True or False?"
    readLn

withArduino :: Arduino () -> IO ()
withArduino (Arduino body) = do
    putStrLn "Pretend we're initializing the arduino."
    body
 
 在其余的代码中，我会假装Arduino和Pin类型是不透明的。 
 
 我们需要一个事件网络来将表示从arduino接收到的信号的输入事件转换为描述我们想要发送给arduino的输出事件。 为了让事情变得非常简单，让我们从一个引脚接收数据，并在另一个引脚上输出完全相同的数据。 
 
eventNetwork :: forall t. Event t Bool -> Event t Bool
eventNetwork = id
 
 接下来，让我们将我们的活动网络连接到外部世界。 当输出事件发生时，我只需将该值写入IORef中，以后可以观察。 
 
main :: IO ()
main = do
    (inputPinAddHandler, fireInputPin) <- newAddHandler
    outputRef <- newIORef False

    let networkDescription :: forall t. Frameworks t => Moment t ()
        networkDescription = do
            -- input
            inputPinE <- fromAddHandler inputPinAddHandler

            -- output
            let outputPinE = eventNetwork inputPinE

            reactimate $ writeIORef outputRef <$> outputPinE
    network <- compile networkDescription
    actuate network

    withArduino $ do
      let inputPin  = pin 1
      let outputPin = pin 2

      -- initialize pins here...

      -- main loop
      loop inputPin outputPin fireInputPin outputRef
 
 注意在主循环之外，只有一次调用reactimate和compile 。 这些功能设置你的事件网络，你不想在每个循环中调用它们。 
 
 最后，我们运行主循环。 
 
loop :: Pin
     -> Pin
     -> (Bool -> IO ())
     -> IORef Bool
     -> Arduino ()
loop inputPin outputPin fireInputPin outputRef = do
    -- read the input from the arduino
    inputValue <- digitalRead inputPin

    -- send the input to the event network
    liftIO $ fireInputPin inputValue

    -- read the output from the event network
    outputValue <- liftIO $ readIORef outputRef

    -- send the output to the arduino
    digitalWrite outputPin outputValue

    loop inputPin outputPin fireInputPin outputRef
 
 注意我们如何使用liftIO与Arduino计算内部的事件网络进行交互。 我们调用fireInputPin来触发一个输入事件，事件网络导致一个输出事件被触发作为响应，并且我们给出的writeIORef用于reactimate导致输出事件的值被写入IORef。 如果事件网络更复杂并且输入事件未触发任何输出事件，则IORef的内容将保持不变。 无论如何，我们可以观察这些内容，并使用它来确定运行哪个Arduino计算。 在这种情况下，我们只需将输出值发送到预定的引脚。 

 
 
How would you execute Arduino actions in reactimate?
 
 
I would cause them to be executed indirectly, by executing an IO action which has an observable side-effect. Then, inside withArduino, I would observe this side-effect and run the corresponding Arduino command.
 
Here's some example code. First, let's get the imports out of the way.
 
{-# LANGUAGE GeneralizedNewtypeDeriving, ScopedTypeVariables #-}

import Control.Monad.IO.Class
import Data.IORef
import Data.Word
import Reactive.Banana
import Reactive.Banana.Frameworks
import Text.Printf
 
Since I do not have an arduino, I'll have to mock up a few methods from hArduino.
 
newtype Arduino a = Arduino (IO a)
  deriving (Functor, Applicative, Monad, MonadIO)

newtype Pin = Pin Word8

pin :: Word8 -> Pin
pin = Pin

digitalWrite :: Pin -> Bool -> Arduino ()
digitalWrite (Pin n) v = Arduino $ do
    printf "Pretend pin %d on the arduino just got turned %s.\n"
           n (if v then "on" else "off")

digitalRead :: Pin -> Arduino Bool
digitalRead (Pin n) = Arduino $ do
    printf "We need to pretend we read a value from pin %d.\n" n
    putStrLn "Should we return True or False?"
    readLn

withArduino :: Arduino () -> IO ()
withArduino (Arduino body) = do
    putStrLn "Pretend we're initializing the arduino."
    body
 
In the rest of the code, I'll pretend that the Arduino and Pin types are opaque.
 
We'll need an event network to transform input events representing signals received from the arduino into output events describing what we want to send to the arduino. To keep things extremely simple, let's receive data from one pin and output the exact same data on another pin.
 
eventNetwork :: forall t. Event t Bool -> Event t Bool
eventNetwork = id
 
Next, let's connect our event network to the external world. When output events occur, I simply write the value into an IORef, which I'll be able to observe later.
 
main :: IO ()
main = do
    (inputPinAddHandler, fireInputPin) <- newAddHandler
    outputRef <- newIORef False

    let networkDescription :: forall t. Frameworks t => Moment t ()
        networkDescription = do
            -- input
            inputPinE <- fromAddHandler inputPinAddHandler

            -- output
            let outputPinE = eventNetwork inputPinE

            reactimate $ writeIORef outputRef <$> outputPinE
    network <- compile networkDescription
    actuate network

    withArduino $ do
      let inputPin  = pin 1
      let outputPin = pin 2

      -- initialize pins here...

      -- main loop
      loop inputPin outputPin fireInputPin outputRef
 
Note how reactimate and compile are only called once, outside the main loop. Those functions setup your event network, you do not want to call them on every loop.
 
Finally, we run the main loop.
 
loop :: Pin
     -> Pin
     -> (Bool -> IO ())
     -> IORef Bool
     -> Arduino ()
loop inputPin outputPin fireInputPin outputRef = do
    -- read the input from the arduino
    inputValue <- digitalRead inputPin

    -- send the input to the event network
    liftIO $ fireInputPin inputValue

    -- read the output from the event network
    outputValue <- liftIO $ readIORef outputRef

    -- send the output to the arduino
    digitalWrite outputPin outputValue

    loop inputPin outputPin fireInputPin outputRef
 
Note how we use liftIO to interact with the event network from inside an Arduino computation. We call fireInputPin to trigger an input event, the event network causes an output event to be triggered in response, and the writeIORef we gave to reactimate causes the output event's value to be written to the IORef. If the event network was more complicated and the input event did not trigger any output event, the contents of the IORef would remain unchanged. Regardless, we can observe that contents, and use it to determine which Arduino computation to run. In this case, we simply send the output value to a predetermined pin.