怎样彻底清除上网历史记录

直接启动startup.bat会自动地配置我们的环境变量(CATALINA_HOME),并且也会有命令行参数的设置. 
试想下,如果环境变量都没有配置好,如何正常配置log4j和加载WEB-INF中的加载类 ?所以这是关键. 
这是startup.bat的内容,如果你想了解更多,可以研究下这个: 
@echo off 
if "%OS%" == "Windows_NT" setlocal 
rem --------------------------------------------------------------------------- 
rem Start script for the CATALINA Server 
rem 
rem $Id: startup.bat 302918 2004-05-27 18:25:11Z yoavs $ 
rem --------------------------------------------------------------------------- 

rem Guess CATALINA_HOME if not defined 
set CURRENT_DIR=%cd% 
if not "%CATALINA_HOME%" == "" goto gotHome 
set CATALINA_HOME=%CURRENT_DIR% 
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome 
cd .. 
set CATALINA_HOME=%cd% 
cd %CURRENT_DIR% 
:gotHome 
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome 
echo The CATALINA_HOME environment variable is not defined correctly 
echo This environment variable is needed to run this program 
goto end 
:okHome 

set EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat 

rem Check that target executable exists 
if exist "%EXECUTABLE%" goto okExec 
echo Cannot find %EXECUTABLE% 
echo This file is needed to run this program 
goto end 
:okExec 

rem Get remaining unshifted command line arguments and save them in the 
set CMD_LINE_ARGS= 
:setArgs 
if ""%1""=="""" goto doneSetArgs 
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1 
shift 
goto setArgs 
:doneSetArgs 

call "%EXECUTABLE%" start %CMD_LINE_ARGS% 

:end